lazy-lambda-calculus: 730f748fb0ffb8fdcfb25b86190be800f8a3b181

     1: with builtins;
     2: with rec {
     3:   # A known-good pinned nixpkgs version
     4:   nixpkgs = overlays: import (fetchTarball {
     5:     name   = "nixpkgs1709";
     6:     url    = https://github.com/NixOS/nixpkgs/archive/17.09.tar.gz;
     7:     sha256 = "0kpx4h9p1lhjbn1gsil111swa62hmjs9g93xmsavfiki910s73sh";
     8:   }) { inherit overlays; config = {}; };
     9: 
    10:   # Avoid rebuilding if only our metadata has changed
    11:   src = filterSource (path: _: !(elem (baseNameOf path)) [
    12:                        ".git" ".gitignore" ".issues" "dist" "dist-newstyle"
    13:                        "nixpkgs.nix" "README" "release.nix" "shell.nix"
    14:                      ])
    15:                      ./.;
    16: 
    17:   # Overrides the pinned haskellPackages set. We don't do it directly in an
    18:   # overlay, since that can break the dependencies of cabal2nix.
    19:   haskellPackages =
    20:     with nixpkgs [];
    21:     haskell.packages.ghc7103.override (old: {
    22:       overrides = self: super: {
    23:         lazy-lambda-calculus = self.callPackage (super.haskellSrc2nix {
    24:           inherit src;
    25:           name = "lazy-lambda-calculus";
    26:         }) {};
    27: 
    28:         lazysmallcheck2012 = self.callPackage (super.haskellSrc2nix {
    29:           name = "lazysmallcheck2012";
    30:           src  = fetchgit {
    31:             url    = http://chriswarbo.net/git/lazy-smallcheck-2012.git;
    32:             rev    = "dbd6fba";
    33:             sha256 = "1i3by7mp7wqy9anzphpxfw30rmbsk73sb2vg02nf1mfpjd303jj7";
    34:           };
    35:         }) {};
    36: 
    37:         syb = self.callHackage "syb" "0.6" {};
    38:       };
    39:     });
    40: };
    41: nixpkgs [
    42:   (self: super: { inherit haskellPackages; })
    43: ]