nix-helpers: d1ab25f03c26a661aaa2f10dff1f6ea5e3f74c06

     1: {
     2:   haskell,
     3:   haskellPackages,
     4:   lib,
     5: }:
     6: with {
     7:   inherit (builtins) filter listToAttrs map;
     8:   oldHaskellPackages = haskellPackages;
     9: };
    10: {
    11:   cabalPlan,
    12:   haskellPackages ? oldHaskellPackages,
    13: }:
    14: with rec {
    15:   namesToVersions = map (pkg: {
    16:     name = pkg.pkg-name;
    17:     value = pkg.pkg-version;
    18:   });
    19: 
    20:   chosenVersions = haskell.lib.packageSourceOverrides (
    21:     listToAttrs (
    22:       namesToVersions (
    23:         filter (pkg: pkg.type != "pre-existing") (
    24:           cabalPlan.install-plan or cabalPlan.json.install-plan
    25:         )
    26:       )
    27:     )
    28:   );
    29: 
    30:   fixes = self: super: {
    31:     # TODO: Disable all tests, to prevent circular dependencies
    32:     mkDerivation =
    33:       lib.setFunctionArgs (
    34:         args: super.mkDerivation (args // { doCheck = false; })
    35:       ) super.mkDerivation
    36:       // {
    37:         original = haskellPackages.mkDerivation;
    38:       };
    39: 
    40:     # The splitmix package lists 'testu01' as a required "system dependency"
    41:     testu01 = null;
    42:   };
    43: };
    44: (haskellPackages.extend fixes).extend chosenVersions